Sorry your browser is not supported!

sync on
sync rate 60
randomize timer()

load sound "whip.wav", 1
load sound "earth slow.wav", 2
load sound "earth fast.wav", 3
load sound "hit tree.wav", 4


load image "rock.bmp", 1


make matrix 1, 1000,1000,10,10
prepare matrix texture 1, 1, 1, 1


load object "dwarf1.x", 1
scale object 1, 500, 500, 500
set object ambient 1, 0
set object speed 1, 30
loop object 1, 327, 360


load object "dwarf2.x", 2
scale object 2, 500, 500, 500
set object ambient 2, 0
set object speed 2, 30
loop object 2, 2, 14

dx# = rnd(1000)
dz# = rnd(1000)

rem radar
make object cone 3, 6
xrotate object 3, 90
fix object pivot 3
position object 3, 0,50,100
color object 3, rgb(255,0,0)
set object ambient 3, 0

DO


  oldstage = stage
  stage = 0
  gosub _controls
  gosub _handle_attack

  if stage <> oldstage
      if stage = 0 then loop object 1, 292, 325
      if stage = 1 then loop object 1, 2, 14
      if stage = 2 then loop object 1, 16, 26
      if stage = 3 then loop object 1, 112, 126 : play sound 1
  endif

  gosub _sounds

  gosub _position_camera
  gosub _position_dwarf

  gosub _handle_dwarf2

  gosub _radar

  center text screen width()/2, 10, "Score: "+str$(score)

  sync
LOOP




_controls:

  if attacking = 0
      if shiftkey()
        speed# = 4
        stage = 2
      else
        speed# = 2
      endif

      if upkey()
        x# = newxvalue(x#, a#, speed#)
        z# = newzvalue(z#, a#, speed#)
        if stage <> 2 then stage = 1
      endif

      if downkey()
        x# = newxvalue(x#, a#, -speed#)
        z# = newzvalue(z#, a#, -speed#)
        if stage <> 2 then stage = 1
      endif

      if rightkey()
        a# = wrapvalue(a#+4)
      endif

      if leftkey()
        a# = wrapvalue(a#-4)
      endif
  endif

  if controlkey() then attacking = 1

RETURN

_position_camera:
  cx# = newxvalue(x#,0, -50)
  cz# = newzvalue(z#,0, -50)
  position camera cx#,80,cz#
  point camera x#,y#,z#
RETURN

_position_dwarf:
  position object 1, x#, y#, z#
  yrotate object 1, a#
RETURN


_handle_attack:
  if attacking = 1
      stage = 3
      if object frame(1) >= 125 then attacking = 0:hit = 0:return


      if distance#(x#,z#,dx#,dz#) < 20^2
        if object frame(1) > 118 and hit = 0
            hit = 1
            inc score, 1
            play sound 4
        endif
      endif

  endif
RETURN


_handle_dwarf2:
  dx# = newxvalue(dx#, da#, 1)
  dz# = newzvalue(dz#, da#, 1)

  if timer() > dtime + direction_change
      dtime = timer()
      direction_change = rnd(3000)+3000
      da# = rnd(360)
  endif

  if dx# > 1000 or dx# < 0 or dz# > 1000 or dz# < 0
      da# = wrapvalue(da# + 180)
  endif

  position object 2, dx#, dy#, dz#
  yrotate object 2, da#
RETURN



_radar:
  ra# = atanfull(dx#-x#, dz#-z#)
  yrotate object 3, ra#

  rx# = newxvalue(x#,180, 10)
  rz# = newzvalue(z#,180, 10)
  position object 3, rx#, ry#, rz#
RETURN


_sounds:
  if stage = 1
      if sound playing(2) = 0 then play sound 2
  endif
  if stage = 2
      if sound playing(3) = 0 then play sound 3
  endif
RETURN

rem returns the squared distance
function distance#(x1 as float, y1 as float, x2 as float, y2 as float)
  d2# = (x1 - x2)^2 + (y1 - y2)^2
endfunction d2#