Something like this?
`Main Source File
sync on : sync rate 0
set window off
autocam off : hide mouse
position camera 0,0,-20
`make crosshair
make object plain 1, 1, 1
color object 1, rgb(255,0,0)
`make object to test
make object cube 2, 10
`center mouse on screen
position mouse screen width()/2,screen height()/2
do
`set variables to move crosshair by mousemovement
objx# = object position x(1)+(mousemovex()/10)
objy# = object position y(1)+(0-(mousemovey()/10))
`set crosshair screen bounds
if objx# > 10 then objx# = 10
if objx# < -10 then objx# = -10
if objy# > 7 then objy# = 7
if objy# < -7 then objy# = -7
`update crosshair position
position object 1, objx#, objy#, -7
`use pick object to see if crosshair is over object
temp = pick object(object screen x(1), object screen y(1), 2, 2)
`if crosshair is over object the recolor crosshair else change it back.
if temp > 0
color object 1, rgb(0,255,0)
else
color object 1, rgb(255,0,0)
endif
sync
loop
There are many ways to do this.
You could even use the texture object command.
sync on : sync rate 0
set window off
`make crosshair images
create bitmap 1,20,20
ink rgb(255,0,0), 0
line 9,2,9,19
line 10,2,10,19
line 11,2,11,19
line 2,9,19,9
line 2,10,19,10
line 2,11,19,11
get image 1, 0, 0, 20, 20, 1
cls
ink rgb(0,255,0), 0
line 9,2,9,19
line 10,2,10,19
line 11,2,11,19
line 2,9,19,9
line 2,10,19,10
line 2,11,19,11
get image 2, 0, 0, 20, 20, 1
cls
delete bitmap 1
autocam off : hide mouse
position camera 0,0,-20
`make crosshair
make object plain 1, 1, 1
texture object 1, 1
set object transparency 1, 1
`make object to test
make object cube 2, 10
`center mouse on screen
position mouse screen width()/2,screen height()/2
do
`set variables to move crosshair by mousemovement
objx# = object position x(1)+(mousemovex()/10)
objy# = object position y(1)+(0-(mousemovey()/10))
`set crosshair screen bounds
if objx# > 10 then objx# = 10
if objx# < -10 then objx# = -10
if objy# > 7 then objy# = 7
if objy# < -7 then objy# = -7
`update crosshair position
position object 1, objx#, objy#, -7
`use pick object to see if crosshair is over object
temp = pick object(object screen x(1), object screen y(1), 2, 2)
`if crosshair is over object the retexture crosshair else change it back.
if temp > 0
texture object 1, 2
else
texture object 1, 1
endif
sync
loop
You will definately want a better mouse to object position control. I just threw that in quickly. It is very jumpy.
