help with static collision box - GameCreators Forum

Author

Message

Johnny Bolt

19

Years of Service

User Offline

Joined: 30th Dec 2004

Location: South Jersey

Posted: 10th Feb 2005 10:40 Edited at: 10th Feb 2005 11:58

Link

I'm not quite sure if I understand the make static collision box command. Can someone please explain the make static collision box and get static collision hit. Mainly what the commands require and how that applies to a 3D space.

What I am trying to accomplish is to know when an object touches a certain section of a 3D box. Would this be the correct way to accomplish this or is there another command that would make this easier. I don't need the sliding collision part of this at least not yet.

Back to top

Profile PM

RiiDii

19

Years of Service

User Offline

Joined: 20th Jan 2005

Location: Inatincan

Posted: 10th Feb 2005 16:01 Edited at: 10th Feb 2005 16:03

Link

Hi Johnny, I'm not sure exactly what you are wanting to accomplish, but I am pretty sure a static collision box is probably not what you want. I haven't used static collision boxes myself, but my understanding is that they are used primarily to block of portions of your game world (like the edge or a cliff).

As far as detecting where one object touches another, well that's something DBPro doesn't do too well by itself. Based on the info you did provide, I can suggest two possibilities.

1) If you want a detailed collision on your box (i.e. down to a pixel or so), you might want to check around for dlls that can do this. I've read about a few,but I have no idea how they work, or how well they work.
2) If you just want a general collision area, like a side, you can;
a) Use math to calculate the collision side
b) Or, you can make a box from 6 plains and re-build the box as needed each frame (DBPro can easily handle this for even a few boxes, but it's a bit of programming). Then just check for collisions against each of the plains.

"Droids don't rip your arms off when they lose." -H. Solo

REALITY II

Back to top

Profile PM Email

RiiDii

19

Years of Service

User Offline

Joined: 20th Jan 2005

Location: Inatincan

Posted: 10th Feb 2005 16:28

Link

Johnny, Also take a look at this code. Again, I don't know if you want detail, or maybe just a side or an angle. This code returns the angle side the "Player" was hit on. You can adjust the angle granularity, but it costs Frame Rate to put it too high (and get little in return). This 'theory' could also be put to use in 3 dimensions instead of just 2 as in the demo here.

Type Coordinates
   x as Float
   y as Float
   z as Float
EndType

Global Object as Coordinates
Global Camera as Coordinates
Global AI as Coordinates

Sync On

Sync Rate 100

Autocam Off

`Make Matrix 1,1000,1000,50,50

`player
Make Object Sphere 1,20
Position Object 1,500,0,500
Set Object Collision Off 1

`AI Object
`Note: Just as my own standard, I always use Object #2 as the AI Object (for no reason, just because).
Make Object Sphere 2,1,8,8
Hide Object 2
Set Object Collision On 2
Set Object Collision to Boxes 2

For j= 3 to 12
   Make Object Cube j,20
   Position Object j, rnd(1000),10,rnd(1000)
   Turn Object Left j,rnd(360)
   Set Object Collision On j
   Set Object Collision To Boxes j
Next j

Do
   Turn Object Left 1,LeftKey()-RightKey()
   Move Object 1,Upkey()-DownKey()
   Status$=NoWalls(1,12)
   Set Cursor 0,0
   Print Status$
   Camera_Follow(1)
   Sync
Loop

Function Camera_Follow(ObjectID)
   Return_Object(ObjectID)
   Position Object 2,Object.x,Object.y,Object.z
   Set Object To Object Orientation 2,1
   Move Object 2,-80
   Pitch Object Up 2,90
   Move Object 2,45
   Return_AI()
   Position Camera AI.x,AI.y,AI.z
   Point Camera Object.x,Object.y,Object.z
EndFunction

Function Return_Object(ObjectID)
Object.x=Object Position X(ObjectID):Object.y=Object Position Y(ObjectID):Object.z=Object Position Z(ObjectID)
EndFunction

Function Return_Camera()
Camera.x=Camera Position X():Camera.y=Camera Position Y():Camera.z=Camera Position Z()
EndFunction

Function Return_AI()
AI.x=Object Position X(2):AI.y=Object Position Y(2):AI.z=Object Position Z(2)
EndFunction

Function NoWalls(ObjectID,Granularity)
Set Object Collision On 2
ObjectOffset#=Object Size(ObjectID)*1.1
angle=360/Granularity:`Get our angle based on how many checks we need to do.
HitAng=0:HitObj=0:Hit$=""
For i = 0 to 360-angle step angle:` and cycle through the checks. Note: it's a full circle. We end up facing the same direction.
   Turn Object Left ObjectID,angle: ` turn the calculated angle
   Flag = 0
   Return_Object(ObjectID)
   Position Object 2,Object.x,Object.y+(ObjectHeight#/2),Object.z:` Start the AI at the Object center
   Set Object to Object Orientation 2,ObjectID:` and orient the AI
   Move Object 2,ObjectOffset#:` Moves the Dist# + Object Size
   Dot Object Screen X(2),Object Screen Y(2): ` A "tracer" for our AI
   If Object Collision (2,0)>0 Then Flag = 1:`Did we hit something at the test position? Flag = 1 = Yes.
   If Flag = 1
      Move Object ObjectID,-1
      HitAng=i+Angle:HitObj=Object Collision (2,0)
      Hit$="Object Hit = " + Str$(HitObj) + ". Hit Angle = " + Str$(HitAng)
   Endif
Next i
EndFunction Hit$

+ Code Snippet

Type Coordinates
   x as Float
   y as Float
   z as Float
EndType

Global Object as Coordinates
Global Camera as Coordinates
Global AI as Coordinates

Sync On

Sync Rate 100

Autocam Off

`Make Matrix 1,1000,1000,50,50

`player
Make Object Sphere 1,20
Position Object 1,500,0,500
Set Object Collision Off 1

`AI Object
`Note: Just as my own standard, I always use Object #2 as the AI Object (for no reason, just because).
Make Object Sphere 2,1,8,8
Hide Object 2
Set Object Collision On 2
Set Object Collision to Boxes 2

For j= 3 to 12
   Make Object Cube j,20
   Position Object j, rnd(1000),10,rnd(1000)
   Turn Object Left j,rnd(360)
   Set Object Collision On j
   Set Object Collision To Boxes j
Next j



Do
   Turn Object Left 1,LeftKey()-RightKey()
   Move Object 1,Upkey()-DownKey()
   Status$=NoWalls(1,12)
   Set Cursor 0,0
   Print Status$
   Camera_Follow(1)
   Sync
Loop


Function Camera_Follow(ObjectID)
   Return_Object(ObjectID)
   Position Object 2,Object.x,Object.y,Object.z
   Set Object To Object Orientation 2,1
   Move Object 2,-80
   Pitch Object Up 2,90
   Move Object 2,45
   Return_AI()
   Position Camera AI.x,AI.y,AI.z
   Point Camera Object.x,Object.y,Object.z
EndFunction


Function Return_Object(ObjectID)
Object.x=Object Position X(ObjectID):Object.y=Object Position Y(ObjectID):Object.z=Object Position Z(ObjectID)
EndFunction

Function Return_Camera()
Camera.x=Camera Position X():Camera.y=Camera Position Y():Camera.z=Camera Position Z()
EndFunction

Function Return_AI()
AI.x=Object Position X(2):AI.y=Object Position Y(2):AI.z=Object Position Z(2)
EndFunction


Function NoWalls(ObjectID,Granularity)
Set Object Collision On 2
ObjectOffset#=Object Size(ObjectID)*1.1
angle=360/Granularity:`Get our angle based on how many checks we need to do.
HitAng=0:HitObj=0:Hit$=""
For i = 0 to 360-angle step angle:` and cycle through the checks. Note: it's a full circle. We end up facing the same direction.
   Turn Object Left ObjectID,angle: ` turn the calculated angle
   Flag = 0
   Return_Object(ObjectID)
   Position Object 2,Object.x,Object.y+(ObjectHeight#/2),Object.z:` Start the AI at the Object center
   Set Object to Object Orientation 2,ObjectID:` and orient the AI
   Move Object 2,ObjectOffset#:` Moves the Dist# + Object Size
   Dot Object Screen X(2),Object Screen Y(2): ` A "tracer" for our AI
   If Object Collision (2,0)>0 Then Flag = 1:`Did we hit something at the test position? Flag = 1 = Yes.
   If Flag = 1
      Move Object ObjectID,-1
      HitAng=i+Angle:HitObj=Object Collision (2,0)
      Hit$="Object Hit = " + Str$(HitObj) + ". Hit Angle = " + Str$(HitAng)
   Endif
Next i
EndFunction Hit$

"Droids don't rip your arms off when they lose." -H. Solo

REALITY II

Back to top

Profile PM Email

Johnny Bolt

19

Years of Service

User Offline

Joined: 30th Dec 2004

Location: South Jersey

Posted: 11th Feb 2005 12:28 Edited at: 11th Feb 2005 12:33

Link

Thanks RiiDii for the response. Great little piece of code. Though it is not quite what I am looking for, it may come in handy later on down the road.

What I am looking for: I am making kind of a 3D Pong game (yea I know it's been done a thousand times but I am trying to teach my 12 year old some of the basics of programing and thought that would be a good place to start).

I want to write a piece of code that will chage the way the ball moves. I want to be able to affect it by where on the paddle it hits(ie: if it hits the left side of the face of the paddle, reverse the direction of the ball: if it hits in the middle of the paddle - bounce in the same direction (you get the idea?)).

I've created the paddle by using the command make object box and then set object collision to boxes. This does what I need it to as far as tracking the collisions.

Is there anyway to know where on the box it hits?

The only true failure is not to try at all...

Back to top

Profile PM

RiiDii

19

Years of Service

User Offline

Joined: 20th Jan 2005

Location: Inatincan

Posted: 11th Feb 2005 14:55 Edited at: 11th Feb 2005 15:07

Link

Sure - it can be easily done. Just make the paddle out of 3 boxes. Keep the three boxes in sync with each other (aligned) and the ball does what you program it to based on which box it collides with. The trick is to make all three boxes look like a single box (and the secret is... make a 4th box larger than the three single boxes and have the 4th box encase the three boxes - and remember to turn the 4th box's collision off. No one ever needs to know the one paddle is actually 4 seperate paddles working together.
Somthing like this: [[B1][B2][B3]]

You could also use some simple math instead. Just get the X coordinate of the ball and the X coordinate of the paddle (Use; Object Position X() ). Then calculate about 1/3 your paddle size (or whatever feels right). Then subract half that distance for the left side and add half that distance for the right side. For example: Paddle Size = 30. 30/3 = 10, and 10/2 = 5.
So Left would be If Object Position X(Ball)<Object Position X(Paddle)-5
Right would be If Object Position X(Ball)>Object Position X(Paddle)+5
Any remamining collisions by default would be the center.

One last method would be a smoother method and the angles would all depend on where your Ball hit on the paddle.
When a collsion is detected, move the ball using something like:
Position Object Ball#, Object Position X(Ball#),Object Position Y(Ball#), Object Position Z(Paddle#)+5
(in place of "+5" use an offset that is 1/2 your Paddle's Z size)
Then point the ball at the paddle's center:
Point Object Ball#,Object Position X(Paddle#),Object Position Y(Ball#),Object Position Z(Paddle#)
Then turn the ball around 180 degrees.
Turn Object Left Ball#,180
Then send the ball off on it's merry way. The ball is heading directly away from the paddle's center, so, the more offset the ball hits the paddle, the more of an angle the ball will leave at.

Any of these will work just fine. Hope this helps.

Edit: When I wrote this, I was thinking a horizontal paddle along the X-axis hitting a ball traveling primarily along the Z-axis. It occurs to me now, that's more like breakout instead of pong, but the concepts are the same.

"Droids don't rip your arms off when they lose." -H. Solo

REALITY II

Back to top

Profile PM Email

Johnny Bolt

19

Years of Service

User Offline

Joined: 30th Dec 2004

Location: South Jersey

Posted: 12th Feb 2005 02:20

Link

Yes that helps alot. I was actually just sitting down to try the first one on my own when I though about checking this thread. Nice to see that I am thinking along the right lines.

Your second idea, I hadn't thought of but make sense.

Your third suggestion is kind of what I was thinking all along, just wasn't quite sure how to make it work. I'm still a little fuzzy on how to make it work but it's a good start and I am going to sit later and work out all three to see which I like working with better.

I'll do this because when I work these kinds of things out, I try to document them well and then store the info for later use in other projects. I have enough little bits of code you could choke a paper sheredder with. Thank God for the digital age. It only eats up drive space.

Thanks for your help and will let you know how I make out.

The only true failure is not to try at all...

Back to top

Profile PM

RiiDii

19

Years of Service

User Offline

Joined: 20th Jan 2005

Location: Inatincan

Posted: 12th Feb 2005 08:05

Link

Johnny, here's an example of the 3rd method:
Warning: Spoiler!

Sync On
Sync Rate 60
AutoCam Off
Global LastX as Float
Global LastZ as Float

Make Object Box 1,60,10,10:` A paddle
Position Object 1,0,10,20
Set Object Collision To Boxes 1

Make Object Sphere 3,10:` A ball
Position Object 3,0,10,250
Turn Object Left 3,rnd(360)

For i = 4 to 7
   Make Object Box i,500,20,10:`Walls
   Set Object Collision To Boxes i
Next i

`Make Playing field
Position Object 4,0,10,490
Position Object 5,-245,10,245
Turn Object Left 5,90
Position Object 6,245,10,245
Turn Object Right 6,90

Position camera 0,500,50
Point Camera 0,0,120

Do
   MoveBall()
   Move Object Right 1,MouseMoveX()
   If Object Position X(1)<-240 Then Position Object 1,-240,Object Position Y(1),Object Position Z(1)
   If Object Position X(1)>240 Then Position Object 1,240,Object Position Y(1),Object Position Z(1)
   Sync
Loop

Function MoveBall()
Move Object 3,3
Select Object Collision(3,0)
   Case 1
      `Point the ball to the center of the paddle
      Point Object 3,Object Position X(1),Object Position Y(3),Object Position Z(1)
      `Turn around 180
      Turn Object Left 3,180
   EndCase
   Case 4,7
      `Far wall/Close wall
      `Determine new bounce direction
      NewX=Object Position X(3)+(Object Position X(3)-LastX)
      NewZ=LastZ
      Point Object 3,NewX,Object Position Y(3),Newz
      Move Object 3,3
   EndCase
   Case 5,6
      `Left & Right walls
      NewX=LastX
      NewZ=Object Position Z(3)+(Object Position Z(3)-LastZ)
      Point Object 3,NewX,Object Position Y(3),Newz
      Move Object 3,3
   EndCase
EndSelect
LastX=Object Position X(3)
LastZ=Object Position Z(3)
EndFunction

+ Code Snippet

Sync On
Sync Rate 60
AutoCam Off
Global LastX as Float
Global LastZ as Float

Make Object Box 1,60,10,10:` A paddle
Position Object 1,0,10,20
Set Object Collision To Boxes 1

Make Object Sphere 3,10:` A ball
Position Object 3,0,10,250
Turn Object Left 3,rnd(360)

For i = 4 to 7
   Make Object Box i,500,20,10:`Walls
   Set Object Collision To Boxes i
Next i

`Make Playing field
Position Object 4,0,10,490
Position Object 5,-245,10,245
Turn Object Left 5,90
Position Object 6,245,10,245
Turn Object Right 6,90

Position camera 0,500,50
Point Camera 0,0,120

Do
   MoveBall()
   Move Object Right 1,MouseMoveX()
   If Object Position X(1)<-240 Then Position Object 1,-240,Object Position Y(1),Object Position Z(1)
   If Object Position X(1)>240 Then Position Object 1,240,Object Position Y(1),Object Position Z(1)
   Sync
Loop

Function MoveBall()
Move Object 3,3
Select Object Collision(3,0)
   Case 1
      `Point the ball to the center of the paddle
      Point Object 3,Object Position X(1),Object Position Y(3),Object Position Z(1)
      `Turn around 180
      Turn Object Left 3,180
   EndCase
   Case 4,7
      `Far wall/Close wall
      `Determine new bounce direction
      NewX=Object Position X(3)+(Object Position X(3)-LastX)
      NewZ=LastZ
      Point Object 3,NewX,Object Position Y(3),Newz
      Move Object 3,3
   EndCase
   Case 5,6
      `Left & Right walls
      NewX=LastX
      NewZ=Object Position Z(3)+(Object Position Z(3)-LastZ)
      Point Object 3,NewX,Object Position Y(3),Newz
      Move Object 3,3
   EndCase
EndSelect
LastX=Object Position X(3)
LastZ=Object Position Z(3)
EndFunction

"Droids don't rip your arms off when they lose." -H. Solo

REALITY II

Back to top

Profile PM Email

Johnny Bolt

19

Years of Service

User Offline

Joined: 30th Dec 2004

Location: South Jersey

Posted: 14th Feb 2005 13:03

Link

Finally decided on a way to get the ball to move the way I want.

I tried the first and the third and didn't really like the way either turned out. I liked the way my current setup works moving the ball and collision, just couldn't get either to work well with my current code. The third way I pretty much had to re-write the entire program. Didn't really want to spend that much time but figured I needed to make sure it wasn't going to work.

Figured that the best attack was your second idea. Since most of the current program moved the ball using the x,y,z... this would be very easy to accomplish. I've pretty much worked the formula of how I want the ball to react just need to write the actual code to make it do it now. Shouldn't take long. Will post again when I have it completed. Should be in a day or two.

The program is coming along nicer then I thought and may actually be worth playing when I'm done. Have a few other idea's that will need help working out. But I don't want to get too far ahead of myself.

Thanks for all your help!

The only true failure is not to try at all...

Back to top

Profile PM

RiiDii

19

Years of Service

User Offline

Joined: 20th Jan 2005

Location: Inatincan

Posted: 14th Feb 2005 17:02

Link

Welcome Johnny. I'll keep an eye on this thread regularly.

"Droids don't rip your arms off when they lose." -H. Solo

REALITY II

Back to top

Profile PM Email

Johnny Bolt

19

Years of Service

User Offline

Joined: 30th Dec 2004

Location: South Jersey

Posted: 15th Feb 2005 11:31 Edited at: 17th Feb 2005 10:58

Link

Got this little game working the way I want. May have been an easier way but I was never one for taking the easy way out. I guess once I get something in my head I stick to it. I'm sure most of your code snippets have only taken you a few minutes to write where I spend hours, but I'm sure the more I write the better I'll become. Ah the pains of being a novice.

I've included a link to a Zip file with the all the media and source files if anyone wants to take a look.

Let me know what you think.

http://home.comcast.net/~johnnybolt/3D_Pong_Game.zip

I've included the source code here without media. Use your own or download the zip file above.

Rem Project: 3D Pong Game
Rem Created: 2/6/2005 11:12:44 AM
Rem ***** Main Source File *****

gosub _gameSetup

do
`--------------------------------------------------------------
gameSpeed = screen fps()/20
if gameSpeed =< 1 then gameSpeed = 2
`------------------------------------------------------------------------******remove*****
gosub _game_Reset
`----------------------------------------------------------------******remove******
gosub _moveBall         `move the ball
gosub _movePaddle_1     `move the paddle
gosub _moveCamera       `move the camera
gosub _move_2_Paddle
`--------------------------------------------------------------******remove******
`these are used for testing to verify positions and flag status
gosub _print
`---------------------------------------------------------------******remove******
sync     `update the screen
loop     `end main loop

_moveBall:
   ` get the current positon of the ball
   ox# = object position x(100)
   oy# = object position y(100)
   oz# = object position z(100)

remstart
this is for the ball movement
xFactor will be set depending on how the ball hits the players paddle
will get the x position of the ball and the x Position of the paddle and determine
when the ball hits the paddle where it hits by looking at the two figures
the center of the paddle will equal where the center of the ball is
if you subtract the paddle x position from the ball x position this should tell
you where on the paddle the ball hits. Change the x and z factor depending where on
the paddle the ball hits. Paddle will need to be divided into 7 sections and will change
the directions as follows:

hit the center of paddle - ball heads straight out from paddle 0 to 1 factor (x to z)
hit in section -1 or +1 ball bounces in same direction on a 1 to 2 factor (x to z)
hit in section -2 or +2 ball bounces in same direction on a 1 to 1 factor (x to z)
hit in section -3 or +3 ball reverses direction at same factor as arriving 2 to 1
remend

if directionX = 1 then x# = x#+xFactor*gameSpeed
   if directionX = 0 then x# = x#-xFactor*gameSpeed

if directionY = 1 then y# = 10 : xro# = xro#-gameSpeed*2 : xrotate object 100,xro#
   if directionY = 0 then y# = 10 : xro# = xro#+gameSpeed*2 : xrotate object 100,xro#

if directionZ = 1 then z# = z#+zFactor*gameSpeed
   if directionZ = 0 then z# = z#-zFactor*gameSpeed

gosub _ballCollision1

position object 100,x#,y#,z#  `moves the ball

`This covers each corner of the paddle
   cbx# = object position x(100) `center of ball X
   cpx# = object position x(2)   `center of paddle X
   cbz# = object position z(100) `center of ball Z
   cpz# = object position z(2)   `center of paddle Z

`if center of ball - center of paddle is between 33 and 40 and the
   `  and if the ball is somewhere even with the paddle then send the ball
   `   off in a different direction
   if cbx# - cpx# => 33 and cbx# - cpx# =< 40 and cbz# =< 80 and cbz# => 62
         directionZ = 1: directionX = 1: xFactor=2: zFactor=1
   endif
   `if center of ball - center of paddle is between -33 and -40
   `  and if ball is somewhere even with the paddle change the direction of the ball
   `  and send off at opposite angle
   if cbx# - cpx# =< -33 and cbx# - cpx# => -40 and z# =< 70 and z# => 62
      directionZ = 1: directionX = 0: xFactor=2: zFactor=1
   endif
   `-------------------------------------------------------------------------
   `Need code similar to above code for other paddle
return

_ballCollision1:
   `sets the new position for the intersect object command for the walls and paddle
   `  and keeps the ball from going too far into wall before reversing
   if directionX = 1 then nx# = x#+8 else nx# = x#-8
   if directionZ = 1 then nz# = z#+8 else nz# = z#-8
`   if directionY = 1 then ny# = y#+8 else ny# = y#-8
   ny# = y#

`this code reverses the direct of the ball and sets the ball back to the old position
`if it hits a wall in any of the three directions
` will need to remove part of this loop
`let the collision check object 1 by itself. This will judge if it hits the wall
`and ball should continue bouncing off wall as it does now.
`Will make an exact check for objects 2 and 3 so we can apply xFactors and zFactors
`depending on how ball hits the paddle ***see ballMove for explanation.

`-----------------------------------------------------------------
   obj=1 `check to see if it hits the wall
   ballHitX = intersect object(obj,ox#,oy#,oz#,nx#,oy#,oz#)

if ballHitX => 1
      x# = ox#
      if directionX=1 then directionX = 0 else directionX = 1
   endif

ballHitY = intersect object(obj,ox#,oy#,oz#,ox#,ny#,oz#)

if ballHitY => 1
      y# = oy#
      if directionY = 1 then directionY = 0 else directionY = 1
   endif

ballHitZ = intersect object(obj,ox#,oy#,oz#,ox#,oy#,nz#)

if ballHitZ => 1
      z# = oz#
      if directionZ = 1 then directionZ = 0 else directionZ = 1
   endif

`-------------------------------------------------------------------
   for paddle=2 to 3    `check to see if it hits either paddle

ballHitX = intersect object(paddle,ox#,oy#,oz#,nx#,oy#,oz#)
      if ballHitX => 1
         x# = ox#
         if paddle = 3 then if directionX=1 then directionX = 0 else directionX = 1
      endif

ballHitY = intersect object(paddle,ox#,oy#,oz#,ox#,ny#,oz#)
      if ballHitY => 1
         y# = oy#
         if paddle = 3 then if directionY = 1 then directionY = 0 else directionY = 1
      endif

ballHitZ = intersect object(paddle,ox#,oy#,oz#,ox#,oy#,nz#)
      if ballHitZ => 1
         z# = oz#
         cbx# = object position x (100) ` center of ball X
         cpx# = object position x(paddle) `center of ball X
         gosub _x_z_Factor
         if paddle = 3 then if directionZ = 1 then directionZ = 0 else directionZ = 1
      endif

next paddle
`-------------------------------------------------------------------

`this is used to keep score
   scoreHitBox = intersect object (10,ox#,oy#,oz#,nx#,ny#,nz#)
   if scoreHitBox => 1 then score = score + 1
   print "Score: ";score

scoreHitBox1 = intersect object (11,ox#,oy#,oz#,nx#,ny#,nz#)
   if scoreHitBox1 => 1 then score1 = score1 + 1
   print "Score1: ";score1

return

_movePaddle_1:

`get position of paddle before the move
   opx1# = object position x (2)
   opy1# = object position y (2)
   opz1# = object position z (2)

opx2# = object position x (3)
   opy2# = object position y (3)
   opz2# = object position z (3)

`controls for Player Paddle
   if upkey()=1
   paddleStopUD = 8    `stops paddle from going through wall
   move object up 2,5
   endif

if downkey()=1
   paddleStopUD = -8    `stops paddle from going through wall
   move object down 2,5
   endif

if rightkey()=1 and controlkey() = 0
   paddleStopLR = 32    `stops paddle from going through wall
   move object right 2,5
   endif

if leftkey()=1 and controlkey() = 0
   paddleStopLR = -32    `stops paddle from going through wall
   move object left 2,5
   endif

if controlkey() = 1 and rightkey() = 1
   paddleStopLR = 32
   move object right 3,5
   endif

if controlkey() = 1 and leftkey() = 1
   paddleStopLR = -32
   move object left 3,5
   endif

`these will control the rotation of the paddle
`   if controlkey()=1
`   ra=ra+1
`   rotate object 2,ra,0,0
`   endif

`   if shiftkey() = 1
`   ra=ra-1
`   rotate object 2,ra,0,0
`   endif

gosub _paddle_1_Collision

return

_move_2_Paddle:

ballMove = object position x (100)  `track the ball
   paddleMove = object position x (3)  `track the paddle

amt = rnd(3):multi = rnd(4)
   move = amt*multi
   if move < 4 then move = 5
   if move > 7 then move = 7
   if ballMove < paddleMove
      move object left 3,move
   endif
   if ballMove > paddleMove
      move object right 3,move
   endif
`   position object 3,ballMove,10,950
   gosub _paddle_2_Collision

return

_paddle_1_Collision:

`this will need to be move into the paddle move command
` so that the paddle will not into move into the  wall area's
   `will also need to look at moving the paddle move into a section of the loop
   `where the paddle to ball collision check is done so that the ball does not
   `move through paddle when the paddle is in motion.

npx1# = object position x (2)
   npy1# = object position y (2)
   npz1# = object position z (2)

paddleHitX = intersect object(1,opx1#,opy1#,opz1#,npx1#+paddleStopLR,opy1#,opz1#)
   if paddleHitX =>1 then npx1# = opx1#

paddleHitY = intersect object(1,opx1#,opy1#,opz1#,opx1#,npy1#+paddleStopUD,opz1#)
   if paddleHitY =>1 then npy1# = opy1#

paddleHitZ = intersect object(1,opx1#,opy1#,opz1#,opx1#,opy1#,npz1#)
   if paddleHitZ =>1 then npz1# = opz1#

position object 2,npx1#,npy1#,npz1#

return

_paddle_2_Collision:

npx2# = object position x (3)
   npy2# = object position y (3)
   npz2# = object position z (3)

paddleHitX = intersect object(1,opx2#,opy2#,opz2#,npx2#+paddleStopLR,opy2#,opz2#)
   if paddleHitX =>1 then npx2# = opx2#

paddleHitY = intersect object(1,opx2#,opy2#,opz2#,opx2#,npy2#+paddleStopUD,opz2#)
   if paddleHitY =>1 then npy2# = opy2#

paddleHitZ = intersect object(1,opx2#,opy2#,opz2#,opx2#,opy2#,npz2#)
   if paddleHitZ =>1 then npz2# = opz2#

position object 3,npx2#,npy2#,npz2#

return

_moveCamera:

cox# = object position x(2)   `current object X (paddle)
   coy# = object position y(2)   `current object Y (paddle)
   coz# = object position z(2)   `current object Z (paddle)
   position camera 0,cox#,coy#+25,coz#-25 `posision camera behind paddle
   point camera 0, x#,y#,z#            `point camera in direction of ball x,y,z

return

_x_z_Factor:

`if ball hits the center of the paddle
   factor = cbx#-cpx#

if factor => -5 and factor <= 5
      xFactor = 0: zfactor = 2: directionX = 0: directionZ = 1
   endif
`------------------------------------------------------------
   ` if ball hits the first level out on right side of center
   if factor => 6 and factor <= 14
      if xFactor = 0 and directionX = 0 and directionZ = 0
         directionX = 1: directionZ = 1
      endif