Hi there
I've tried clicking on your link to your Source Code, but an error popped up
(probably a network error).
Anyway, here is my take on your situation. Instead of
GLUE OBJECT commands, I've used
POSITION OBJECT commands instead. I think you'll find the latter to be more effective.
Pseudo-Language (common language) Definition
STEP 1: Make the world and the objects (player and carry object)
STEP 2: Allow player object movement
STEP 3: Position carry object (maybe a few steps to the right)
STEP 4: If command is given to drop object, then release the carry object and make it fall to the ground.
STEP 5: If the object reaches floor, stop it from moving
DBC Language
Here is a demo code showing how to do the above. I assume you have some prior knowledge with
NEWXVALUE and related commands. Note, however, that this was created with a 'plane dropping bomb' picture in mind, but the concept is still rather the same:
REM ************************************************************************************
REM FALLING OBJECT TO GROUND
REM By: HWT Date: 8th April 2005
REM This demo shows how to make an object fall to the ground after having been attached
REM to another 'host' object
REM ************************************************************************************
`Sync
sync on : sync rate 0
`Make objects and matrix
make object cube 1,50
make object sphere 2,25
make matrix 1,2500,2500,15,15
REM MAIN PROGRAM LOOP
do
`Handling plane-like movement:
if upkey()=1 then move object 1,3
if downkey()=1 then move object 1,-3
if leftkey()=1 then yrotate object 1,wrapvalue(object angle y(1)-5.0)
if rightkey()=1 then yrotate object 1,wrapvalue(object angle y(1)+5.0)
`Update ship's position (completely separate from others)
position object 1,object position x(1),150,object position z(1)
`Handling drop command
if returnkey()=1 then state=1
`If sphere isn't dropped
if state=0
`Store the old positions of the ship (for later)
oldx#=object position x(2)
oldz#=object position z(2)
`Update ship's, sphere's and camera's position
position object 2,newxvalue(object position x(1),object angle Y(1)+90,30),object position Y(1),newzvalue(object position z(1),object angle Y(1)+90,30)
position camera object position x(1),object position y(1)+25,object position z(1)-200
`Output
center text 320,0,"USE THE ARROW KEYS TO MOVE AND ENTER KEY TO DROP SPHERE"
endif
`If sphere is dropped...
if state=1
`Position sphere in the old positions (making it seem like it's falling away)
position object 2,oldx#,newyvalue(object position Y(2),object angle x(2)+90,2.0),oldz#
`Update camera
position camera object position x(2),object position y(2)+25,object position z(2)-200
`If sphere hits the ground, then change state variable to stop the downward moving process
if object position y(2)<=get ground height(1,object position x(2),object position z(2)) then state=2
`Output
center text 320,0,"BOMBS AWAY!"
endif
sync : loop
If you didn't understand something, please don't hesitate to ask
HelloWorld Tommorrow
