You can of course use the new 5.8 commands to texture each side with a different part of 1 image. This code will make an image 3 by 2 in format:
123
456
i.e 6 different images in one image, or comment out the maketexture command and load in your own.
sync on : sync rate 60 : autocam off
` make a texture (3 by 2) or load one in
makeatexture()
` make an object
make object cube 1,10
texture object 1,1
` make object to show what image looks like
make object plain 2,80,30
texture object 2,1
position object 2,0,0,10
` rearrange uv coordinates - faces are ordered
` front, back, top, bottom, right, left
lock vertexdata for limb 1,0
for face=1 to 6
for corner=1 to 4
vert=((face-1)*4)+corner-1
u#=get vertexdata u(vert)
v#=get vertexdata v(vert)
my=(face-1)/3
mx=face-(my*3)-1
newu#=((mx+u#)/3.0)
newv#=((my+v#)/2.0)
set vertexdata uv vert,newu#,newv#
next corner
next face
unlock vertexdata
position camera 0,0,-50
do
control camera using arrowkeys 0,1,1
turn object left 1,0.5
pitch object up 1,0.3
sync
loop
function makeatexture()
ink rgb(255,0,0),0 : box 0,0,128,128
ink rgb(0,255,0),0 : box 128,0,256,128
ink rgb(0,0,255),0 : box 256,0,384,128
ink rgb(255,0,255),0 : box 0,128,128,256
ink rgb(255,255,0),0 : box 128,128,256,256
ink rgb(0,255,255),0 : box 256,128,384,256
s=0
savetextsize=text size()
set text size 60
ink rgb(255,255,255),0
for y=0 to 1
for x=0 to 2
inc s
cx=(x*128)+64
cy=(y*128)+64
s$=str$(s)
text cx-(text width(s$)/2),cy-(text height(s$)/2),s$
circle cx,cy,60
next x
next y
set text size savetextsize
get image 1,0,0,384,256,1
endfunction
Boo!
