for DBC (so should should translate identically into DBP)
something like this:
sync rate 0
sync on
do
cls
rem check input keys
if leftkey()=1 then dec circleX
if rightkey()=1 then inc circleX
if upkey()=1 then dec circleY
if downkey()=1 then inc circleY
rem keep circle on screen
if circleX < 10 then circleX = 10
if circleX > (screen width() - 10) then circleX = (screen width() - 10)
if CircleY < 10 then circleY = 10
if circleY > (screen height() - 10) then circleY = (screen height() - 10)
rem set the ink to to blue - uber colour
ink rgb(0,63,255),1
rem draw the circle
circle CircleX,CircleY,20
sync
loop
camera doesn't affect circles or any other 2D shape...
if your game has 3D as well, such as your circle is a reticle. then use draw to front before it enters the loop.
managing and moving several circles may be harder, as long you draw one circle before trying to move the next one. DBC certainly doesn't have commands to move 2D graphics like it does for 3D ones, but it shouldn't be too hard...
Example:
sync rate 0
sync on
Circle2XDirection=1 `1 for right 0 for left
Circle2YDirection=1 `1 for down 0 for up
circle2X=25
circle2Y=75
do
cls
rem check input keys
if leftkey()=1 then dec circleX
if rightkey()=1 then inc circleX
if upkey()=1 then dec circleY
if downkey()=1 then inc circleY
rem keep circle on screen
if circleX < 10 then circleX = 10
if circleX > (screen width() - 10) then circleX = (screen width() - 10)
if circleY < 10 then circleY = 10
if circleY > (screen height() - 10) then circleY = (screen height() - 10)
rem set the ink to to blue - uber colour
ink rgb(0,63,255),1
rem draw the circle
circle circleX,circleY,20
rem another one that just bounces around
if circle2XDirection = 0 then dec circle2X
if circle2XDirection = 1 then inc circle2X
if circle2YDirection = 0 then dec circle2Y
if circle2YDirection = 1 then inc circle2Y
rem keep this one on screen
if circle2X = 10 then circle2XDirection = 1
if circle2X > (screen width() - 10) then circle2XDirection = 0
if circle2Y < 10 then circle2YDirection = 1
if circle2Y > (screen height() - 10) then circle2YDirection = 0
rem draw this one red
ink rgb(255,0,0),1
rem and place it
circle circle2X,circle2Y,20
sync
loop
controlling 2 circles...
hope that helps...
...maybe one day I'll finish a project
