Sure can when I get home (in about 11 hours) unless someone else beats me to it.
[edit] Here is a basic example.
`basic camera setup
sync on : sync rate 30
hide mouse : autocam off
autocam off
position camera 5, 200, 5
`make texture or load your own
for i = 1 to 20
print "AAAAAAAAAA"
next i
get image 1, 0, 0, 32, 32
cls
` Load texture for matrix
`load image "grass2a.png", 1
`make basic matrix
make matrix 1, 100, 100, 10, 10
`texture matrix
prepare matrix texture 1, 1, 1, 1
`raise matrix entire matrix above 0
for i = 0 to 10
for j = 0 to 10
set matrix height 1, i, j, 150
next j
next i
`make a pit to fall into and kill him
for i = 4 to 6
for j = 4 to 6
set matrix height 1, i, j, 0
next j
next i
`save matrix changes
update matrix 1
`set player to living
player_life = 1
do
`if player is alive
set cursor 5,5
if player_life = 1
`basic mouselook code
rotate camera camera angle x()+(mousemovey()/2),camera angle y()+(mousemovex()/2),0
if camera angle x()>90 then xrotate camera 90
if camera angle x()<-90 then xrotate camera -90
cx#=camera angle x() : cy#=camera angle y() : cz#=camera angle z()
`simple movement
if upkey()=1
xrotate camera 0: move camera 1: xrotate camera cx#
endif
if downkey()=1
xrotate camera 0: move camera -1: xrotate camera cx#
endif
if rightkey()=1
xrotate camera 0: yrotate camera cy# + 90: move camera 1: xrotate camera cx#: yrotate camera cy#
endif
if leftkey()=1
xrotate camera 0: yrotate camera cy# - 90: move camera 1: xrotate camera cx#: yrotate camera cy#
endif
`print status
print "Avoid the pit or you will die"
else
`when dead make player fall over
if camera angle z() > -90
roll camera right 15
endif
`print status
print "You are dead ... Press return key to reset"
endif
`get ground height
objx# = camera position x()
objz# = camera position z()
ground# = get ground height(1,objx#, objz#) + 1
`set player to dead if ground is 1 or less
if ground# <= 1
player_life = 0
endif
`reset player if dead
if returnkey()=1
objx# = 5
objz# = 5
ground# = 200
player_life = 1
rotate camera 0, 0, 0
endif
`update player to the matrix ground level
position camera objx#, ground#, objz#
`update screen
sync
loop
