Alright. I'll write you a simple sample in DBC
Hold on...
Okay, here it is. Hope it helps:
rem ******************************
rem *COMBINE IMAGES USING SPRITES*
rem ******************************
rem ----------------------------------------
rem |If you have any questions, just ask :)|
rem ----------------------------------------
rem Setup our little demo,
sync on
sync rate 60
rem Create a sample image. It's image 1.
rem (for some reason my DBC doesn't like boxes on bitmaps. I had to make one
rem using lines. However, this is extremely unimportant. Keep reading on.)
create bitmap 1,100,100
ink rgb(255,0,0),0
for l = 1 to 100
line 0,l,100,l
next l
ink rgb(255,255,255),0
text 0,0,"ONE==========="
get image 1,0,0,100,100
delete bitmap 1
rem Create another sample image, but it's image 2.
create bitmap 1,100,100
ink rgb(0,255,0),0
for l = 1 to 100
line 0,l,100,l
next l
ink rgb(255,255,255),0
text 0,0,"TWO==========="
get image 2,0,0,100,100
delete bitmap 1
rem Create a sprite from our sample image. Place it at 0,0 for now.
sprite 1,0,0,1
rem Create another sprite from our other sample image.
sprite 2,0,0,2
rem Change the sizes of the sprites to 100x100 each.
size sprite 1,100,100
size sprite 2,100,100
rem Now, hide the sprites, as they will not be the ones who actually get
rem put into the bitmap.
hide sprite 1
hide sprite 2
rem Paste the images of the sprites onto a bitmap.
rem First, make the bitmap.
create bitmap 1,200,100
rem Now, paste the sprites. The sprite's position is based on its
rem top left corner.
rem Paste sprite 1's image at 0,0, or the top left of the bitmap.
Paste sprite 1,0,0
rem Paste sprite 2's image at 100,0, which is just to the right of
rem the first image, because the first image was 100 units in width.
Paste sprite 2,100,0
rem Make the new bitmap that has the combined images into image 3.
get image 3,0,0,200,100
rem delete the un-needed bitmap
delete bitmap 1
rem Finally, paste image 3 to the screen, and allow you to look at it.
Paste image 3,0,0
suspend for key
