Using sparky's dll with dbc - GameCreators Forum

Author

Message

Lucifer

18

Years of Service

User Offline

Joined: 26th Dec 2005

Location:

Posted: 31st Dec 2006 04:05 Edited at: 31st Dec 2006 04:14

Link

I'm sorry for asking another question about collision please dont get pissed

I am just trying to experiment with sparky's collision dll and there is something i dont understand, i find it very hard to find something that answers my question, dont think i didnt search... please (if anyone knows about a tutorial/Code that shows me how this works please dont flame me

tell me about the link, when i searched i only found stuff that explained how sparky's dll 2 for dbpro worked).. Now, i made this code: just to experiment with it and trying to learn..

+ Code Snippet

Rem setup things
set window on
Sync on : sync rate 50
hide mouse
autocam off
#include functions.dba

make object cube 1,5
position object 1,0,0,-20

make object box 2,20,100,30
position object 2,10,0,10

position camera -5,10,-5

setupObjectDBC(1,1,0)
setupObjectDBC(2,2,0)

do

yangle#=object angle y(1)

if upkey()=1 then move object 1,0.5
if downkey()=1 then move object 1,-0.5
if leftkey()=1 then yrotate object 1,wrapvalue(yangle#-2)
if rightkey()=1 then yrotate object 1,wrapvalue(yangle#+2)

   Rem get player object position and store in X# and Z#
   X# = Object position x(1)
   Z# = Object position z(1)
   Y# = Object position Y(1)

   Rem point the camera at the player object
   Point camera X#,Y#,Z#


if intersectObjectDBC(2,1,oldx#,oldy#,oldz#,x#,y#,z#,excludeObj)

position object 1,x#,0,z#

endif

updateObjectDBC(1)

   sync

loop

From how i understand it, (i am sure i am wrong) intersectobjectdbc is like the object collision(2, 1)???.

if anyone wants to show me how this works i will be very happy because i will learn from it, i am not asking random questions.

i did check out ruccus dll resource post and tdk's post on collision but i didnt find anything that explained what i'm trying to learn. the only thing i found at ruccus'es post was that sliding collision thingy, but it only works with dbpro..

Me+indi... yes...

Back to top

Profile PM

RUCCUS

19

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 31st Dec 2006 18:58

Link

Raycasting (what the intersect object command does) is pretty simple. Think of it as a laser. You specify the laser's starting and ending coordinates, and the laser is then projected between those 2 points. This laser constantly checks if any polygons of the model you specify pass through the laser. If a polygon is hit, the laser bounces back and returns the distance to the point of collision.

Why's raycasting good? Using the object hit and object collision commands aren't polygonal, all they do is use either spheres or boxes that are wrapped around each object, and then the computer checks if these two collision boxes/spheres overlap.

Sparky's intersect object command goes like this;

SC_intersectObject(object, x1, y1, z1, x2, y2, z2)

object is the object you want to detect for intersection.

x1/y1/z1 is the starting location of the laser.

x2/y2/z2 is the ending location of the laser.

Here's a simple program showing how the system works. Press the up/down key to move backward/forward. When you run into the laser, the words "HIT" will appear in the top left of the screen.

+ Code Snippet


SYNC ON:SYNC RATE 0:AUTOCAM OFF:HIDE MOUSE

`Make player object
MAKE OBJECT CUBE 1,10
SC_setupObject 1,0,0

`Make a laser object (has no effect on the collision, just visual junk)
MAKE OBJECT BOX 2,200,1,1
COLOR OBJECT 2,RGB(255,000,000)
GHOST OBJECT ON 2
POSITION OBJECT 2,0,0,50

`Orient the camera
POSITION CAMERA 0,100,0
POINT CAMERA 0,0,0

`Main loop
DO

   `Object movement
   MOVE OBJECT 1, (UPKEY()-DOWNKEY())*0.1

   `Update the player object after its moved
   SC_updateObject 1

   `Now we detect for intersection
   C# = SC_intersectObject(1,-100,0,50,100,0,50)

   `If an intersection occured (meaning C# must be greater than 0)
   IF C#
      `Display "HIT!"
      TEXT 0,0,"HIT!"
   ENDIF

   `Refresh the screen
   SYNC

`Repeat
LOOP

`Include this command for sparky's dll to work
DELETE MEMBLOCK 1

Raycasting has tonnes of uses. Project a ray from the user's old position to their new position, and you can detect if theyve hit any polygons on a complex map object. Shoot a ray from their gun to a point infront of their gun, and you can check if theyve shot anyone, or better yet, get the polygon they shot on the wall, and position a decal of a bullet hole there. Setup a bunch of lasers spinning randomly in a room detecting if the user touches a ray, if so tell them theyve failed their mission.

Hope that helps a bit,
- RUC'

Back to top

Profile PM Email Website

Lucifer

18

Years of Service

User Offline

Joined: 26th Dec 2005

Location:

Posted: 31st Dec 2006 19:40

Link

hey thanks ruccus, i fixed the code so it works for dbc, but there is one thing i cant seem to figure out..

+ Code Snippet

SYNC ON:SYNC RATE 0:AUTOCAM OFF:HIDE MOUSE

#include functions.dba

`Make player object
MAKE OBJECT CUBE 1,10
setupObjectDBC(1,0,0)

`Make a laser object (has no effect on the collision, just visual junk)
MAKE OBJECT BOX 2,200,1,1
COLOR OBJECT 2,RGB(255,000,000)
GHOST OBJECT ON 2
POSITION OBJECT 2,0,0,50

`Orient the camera
POSITION CAMERA 0,100,0
POINT CAMERA 0,0,0

`Main loop
DO

   `Object movement
   If upkey()=1 then move object 1,3


   `Update the player object after its moved
   updateObjectDBC(1)

   `Now we detect for intersection
   C# = intersectObjectDBC(1,-100,0,50,100,0,50)

   `If an intersection occured (meaning C# must be greater than 0)
   IF C#
      `Display "HIT!"
      TEXT 0,0,"HIT!"
   ENDIF

   `Refresh the screen
   SYNC

`Repeat
LOOP

`Include this command for sparky's dll to work
DELETE MEMBLOCK 1

at the intersectObjectDBC(1,-100,0,50,100,0,50) i get an error saying "Syntax error. Parameters differ between function call and call decloration at line 90.. any ideas?

i like pancakes..

Back to top

Profile PM

RUCCUS

19

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 31st Dec 2006 20:32

Link

My guess is you've left out a needed parameter for the DBC version to work. Not sure what though. In DBP if you use an extra param or not enough params in a function call, you get an error along the lines of "Syntax doesnt match: "with a list of the function syntax. I guess in DBC the error is different.

If I could see the functions.dba I could help more.

Back to top

Profile PM Email Website

Lucifer

18

Years of Service

User Offline

Joined: 26th Dec 2005

Location:

Posted: 31st Dec 2006 21:33

Link

here it is

function setupObjectDBC(objNum,groupNum,objectType)
    commonSetup(objNum)

vertData = get memblock ptr(254)
    objectData = get memblock ptr(255)
    call dll 1,"setupObject",objNum,groupNum,objectType,vertData,objectData

delete memblock 254
endfunction

function setupComplexObjectDBC(objNum,groupNum,facesPerNode)
    commonSetup(objNum)

vertData = get memblock ptr(254)
    objectData = get memblock ptr(255)
    call dll 1,"setupComplexObject",objNum,groupNum,facesPerNode,vertData,objectData

delete memblock 254
endfunction

function commonSetup(objNum)
    if dll exist(1)=0 then load dll "DBCcollision.dll",1
    if memblock exist(255)=0 then make memblock 255,24

x#=object position x(objNum)
    y#=object position y(objNum)
    z#=object position z(objNum)
    angx#=object angle x(objNum)
    angy#=object angle y(objNum)
    angz#=object angle z(objNum)

write memblock float 255,0,x#
    write memblock float 255,4,y#
    write memblock float 255,8,z#
    write memblock float 255,12,angx#
    write memblock float 255,16,angy#
    write memblock float 255,20,angz#

position object objNum,0,0,0
    rotate object objNum,0,0,0
    make mesh from object 255,objNum
    make memblock from mesh 254,255
    delete mesh 255
    position object objNum,x#,y#,z#
    rotate object objNum,angx#,angy#,angz#
endfunction

function updateObjectDBC(objNum)
    if memblock exist(255)=0 then make memblock 255,24

write memblock float 255,0,object position x(objNum)
    write memblock float 255,4,object position y(objNum)
    write memblock float 255,8,object position z(objNum)
    write memblock float 255,12,object angle x(objNum)
    write memblock float 255,16,object angle y(objNum)
    write memblock float 255,20,object angle z(objNum)

objectData = get memblock ptr(255)

call dll 1,"updateObject",objNum,objectData
endfunction

function intersectObjectDBC(objNum,groupFlag,oldx#,oldy#,oldz#,x#,y#,z#,excludeObj)
    collide=call dll(1,"intersectObject",objNum,groupFlag,oldx#,oldy#,oldz#,x#,y#,z#,excludeObj)
endfunction collide

function setObjectCollisionOnDBC(objNum)
    call dll 1,"set_object_collision_on",objNum
endfunction

function setObjectCollisionOffDBC(objNum)
    call dll 1,"set_object_collision_off",objNum
endfunction

function collisionStatusDBC(objNum)
    result=call dll(1,"collisionstatus",objNum)
endfunction result

function getStaticCollisionX()
    result#=call dll(1,"getStaticCollisionX")
endfunction result#

function getStaticCollisionY()
    result#=call dll(1,"getStaticCollisionY")
endfunction result#

function getStaticCollisionZ()
    result#=call dll(1,"getStaticCollisionZ")
endfunction result#

function getCollisionNormalX()
    result#=call dll(1,"getCollisionNormalX")
endfunction result#

function getCollisionNormalY()
    result#=call dll(1,"getCollisionNormalY")
endfunction result#

function getCollisionNormalZ()
    result#=call dll(1,"getCollisionNormalZ")
endfunction result#

+ Code Snippet

function setupObjectDBC(objNum,groupNum,objectType)
    commonSetup(objNum)

    vertData = get memblock ptr(254)
    objectData = get memblock ptr(255)
    call dll 1,"setupObject",objNum,groupNum,objectType,vertData,objectData

    delete memblock 254
endfunction

function setupComplexObjectDBC(objNum,groupNum,facesPerNode)
    commonSetup(objNum)

    vertData = get memblock ptr(254)
    objectData = get memblock ptr(255)
    call dll 1,"setupComplexObject",objNum,groupNum,facesPerNode,vertData,objectData

    delete memblock 254
endfunction

function commonSetup(objNum)
    if dll exist(1)=0 then load dll "DBCcollision.dll",1
    if memblock exist(255)=0 then make memblock 255,24

    x#=object position x(objNum)
    y#=object position y(objNum)
    z#=object position z(objNum)
    angx#=object angle x(objNum)
    angy#=object angle y(objNum)
    angz#=object angle z(objNum)

    write memblock float 255,0,x#
    write memblock float 255,4,y#
    write memblock float 255,8,z#
    write memblock float 255,12,angx#
    write memblock float 255,16,angy#
    write memblock float 255,20,angz#

    position object objNum,0,0,0
    rotate object objNum,0,0,0
    make mesh from object 255,objNum
    make memblock from mesh 254,255
    delete mesh 255
    position object objNum,x#,y#,z#
    rotate object objNum,angx#,angy#,angz#
endfunction

function updateObjectDBC(objNum)
    if memblock exist(255)=0 then make memblock 255,24

    write memblock float 255,0,object position x(objNum)
    write memblock float 255,4,object position y(objNum)
    write memblock float 255,8,object position z(objNum)
    write memblock float 255,12,object angle x(objNum)
    write memblock float 255,16,object angle y(objNum)
    write memblock float 255,20,object angle z(objNum)

    objectData = get memblock ptr(255)

    call dll 1,"updateObject",objNum,objectData
endfunction

function intersectObjectDBC(objNum,groupFlag,oldx#,oldy#,oldz#,x#,y#,z#,excludeObj)
    collide=call dll(1,"intersectObject",objNum,groupFlag,oldx#,oldy#,oldz#,x#,y#,z#,excludeObj)
endfunction collide

function setObjectCollisionOnDBC(objNum)
    call dll 1,"set_object_collision_on",objNum
endfunction

function setObjectCollisionOffDBC(objNum)
    call dll 1,"set_object_collision_off",objNum
endfunction

function collisionStatusDBC(objNum)
    result=call dll(1,"collisionstatus",objNum)
endfunction result

function getStaticCollisionX()
    result#=call dll(1,"getStaticCollisionX")
endfunction result#

function getStaticCollisionY()
    result#=call dll(1,"getStaticCollisionY")
endfunction result#

function getStaticCollisionZ()
    result#=call dll(1,"getStaticCollisionZ")
endfunction result#

function getCollisionNormalX()
    result#=call dll(1,"getCollisionNormalX")
endfunction result#

function getCollisionNormalY()
    result#=call dll(1,"getCollisionNormalY")
endfunction result#

function getCollisionNormalZ()
    result#=call dll(1,"getCollisionNormalZ")
endfunction result#

i like pancakes..

Back to top

Profile PM

RUCCUS

19

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 31st Dec 2006 21:36

Link

Yeah, see the function intersectObjectDBC takes a last parameter called ExcludeObject. Put an additional 0 for the last parameter and it'll work.

Back to top

Profile PM Email Website

Lucifer

18

Years of Service

User Offline

Joined: 26th Dec 2005

Location:

Posted: 31st Dec 2006 22:51

Link

no it still gives me the same error message

i like pancakes..

Back to top

Profile PM

RUCCUS

19

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 1st Jan 2007 01:12

Link

Sorry, theres another parameter I missed called groupFlag. Id show you how to fix it, but you need to understand this.

Lets say we made a function called add, and it returned the sum of 2 numbers.

+ Code Snippet

FUNCTION add(num1#,num2#)
   sum# = num1#+num2#
ENDFUNCTION sum#

So far so good. Now, we call the function;

+ Code Snippet

answer = add(2,5)

Which would make answer equal 7, right?

So far so good, because we gave the required parameters. Now, what if we did this?

+ Code Snippet

answer = add(5)

You'd get the error youre getting now. Do you see why? Its because we only gave one parameter, when the function calls for 2.

Again, you'd get the error if you gave too many parameters;

+ Code Snippet

answer = add(2,5,9)

Because the function doesnt know what to do with the last parameter.

So, if you look in that functions.dba file, and you find the intersectObjectDBC command, you'll see this is all of it's parameters;

(objNum,groupFlag,oldx#,oldy#,oldz#,x#,y#,z#,excludeObj)

Now its just a matter of filling in the data. Right now, you're calling the function without providing a groupFlag number. The groupFlag number tells the system if you want to check for intersection with an entire group, or just 1 object. In our case its just 1 object, so we set the groupFlag to 0. So, the final command should go like this;

+ Code Snippet

intersectObjectDBC(1,0,-100,0,50,100,0,50,0)

On a side note, I recognize these commands from sparky's old dll. Have you tried using his later version 2 release? Im pretty sure right now you're not, but I could be wrong, as Im using the dbp version.

For version 2 just search for collision and click on the thread titled "DBP Collision Plugin v2" (or something like that).

- RUC'

Back to top

Profile PM Email Website

Lucifer

18

Years of Service

User Offline

Joined: 26th Dec 2005

Location:

Posted: 1st Jan 2007 02:02 Edited at: 1st Jan 2007 02:02

Link

thanks for explaining that ruccus..

i think that the v2 dll is only for dbpro

i will check it out and see if there is a dbc version..

and this is weird.. i get the same error message, even with the new code.. huh.. me dont understand why..

i like pancakes..

Back to top

Profile PM

RUCCUS

19

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 1st Jan 2007 03:49

Link

Thats weird... you might wana make a seperate post about that or head over to IRC for help, I cant see any other reason that it shouldnt be working. Make a post in the DBC Board titled something like "DBC Parameter Mismatch with Sparky's Dll" explaining the problem, a link to this thread, and you're current code, and you might get some help there.

Back to top

Profile PM Email Website

Lucifer

18

Years of Service

User Offline

Joined: 26th Dec 2005

Location:

Posted: 1st Jan 2007 04:20

Link

ok, i'll make a post in the dbc boards tomorrow explaining the problem and stuffz.. thanks for all your help ruccus..

love ya....

i like pancakes..

Back to top

Profile PM

Robot

20

Years of Service

User Offline

Joined: 27th May 2004

Location:

Posted: 8th Jan 2007 08:22

Link

If this has already been answered somewhere then ignore me but I think the error is arising from trying to give the function an integer where it expects a float. If you put a ".0" on all the 3D world co-ordinates then I think it should work.

Back to top

Profile PM

RUCCUS

19

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 9th Jan 2007 02:12

Link

That mightve been it, I dont have DBC so I dont know how strictly it handles function parameters, in DBP passing an integer for a float is fine though. Chances are thats the case, they need to be decimals.

Back to top

Profile PM Email Website

Sorry your browser is not supported!

Newcomers DBPro Corner / Using sparky's dll with dbc