Wtf Keep getting Parameter dont exist

Author

Message

white boy kyle

18

Years of Service

User Offline

Joined: 5th Feb 2007

Location:

Posted: 9th Feb 2007 21:14

Link

+ Code Snippet

mainmenu:
cls

Sync On : Sync Rate 40
Do
if Button(20,55,"New Game")=1 then goto question2
if button(20,135,"Multiplayer")=1 then print "Try Again"
If Button(20,295,"Exit")=1 then print "Try Again"
if button(20,215,"Options")=1 then print "Try Again"
sync
loop

question2:
cls

Sync On : Sync Rate 0

do
If button(20,55,"Set up Game")=1 then goto mainmenu:
sync
loop

Keeps saying
Syntaxt Error: Unreconized Parameter on this line
if Button(20,55,"New Game")=1 then goto question2

Back to top

Profile PM

blanky

20

Years of Service

User Offline

Joined: 3rd Aug 2004

Location: ./

Posted: 9th Feb 2007 22:50 Edited at: 9th Feb 2007 22:56

Link

Where is your Button() function?

Also, you say:

Quote: "
If button(20,55,"Set up Game")=1 then goto mainmenu:
"

The : on the end of 'mainmenu' you use only to define labels, not when you're actually going to them. It's probably this stopping it from working, assuming Button() is there.

-=-=- Activate asshat mode. -=-=-
Warning: This post may contain bloatage.

Back to top

Profile PM Email Website

TDK

Retired Moderator

22

Years of Service

User Offline

Joined: 19th Nov 2002

Location: UK

Posted: 9th Feb 2007 22:50

Link

The function call parameters and function header parameters do not match.

As you didn't post the function we can't be more specific.

And try to refrain from using abbreviations like you used in the topic line please. It's not so bad in the main body text of a post, but in the topic line it is a bit 'in your face'.

TDK_Man

Back to top

Profile PM Email Website

Kieran

18

Years of Service

User Offline

Joined: 6th Aug 2006

Location: Hamilton, New Zealand

Posted: 9th Feb 2007 23:21

Link

this is for grog grueslayer, he hates goto
try not to use goto there are better ways that cause your code to not be so messy...instead of if button(newgame)=1 then goto question 2

just use
if button(newgame)=1 then exit

that will exit the loop instead of using labels

Back to top

Profile PM

Bluestar4

19

Years of Service

User Offline

Joined: 19th Dec 2005

Location: USA

Posted: 9th Feb 2007 23:26

Link

this is one instance where goto needs to be gone and you should use subs,functions, and repeat until loops.

Bluestar4~
http://www.geocities.com/bluestar4games

Back to top

Profile PM Email

TDK

Retired Moderator

22

Years of Service

User Offline

Joined: 19th Nov 2002

Location: UK

Posted: 9th Feb 2007 23:34 Edited at: 9th Feb 2007 23:34

Link

I was going to mention that lol - but I thought people might be getting tired of my ranting about the evil Goto command!

The same goes for my relentless tutorial plugging. But in this case they might help white boy kyle.

Check out the Layout, Structure & Style tutorial (number 2) at:

http://forum.thegamecreators.com/?m=forum_view&t=99497&b=7

TDK_Man

Back to top

Profile PM Email Website

Grog Grueslayer

Valued Member

19

Years of Service

User Offline

Joined: 30th May 2005

Playing: Green Hell

Posted: 10th Feb 2007 21:53

Link

@ Kieran

Amen!

@ TDK

People just don't like to be told the truth sometimes.

@ white boy kyle

One set of commands that'll help wrangle menus and (looking at your other messages) give you the ability to pick random questions from a list of many is the select/case commands.

cls
Sync On : Sync Rate 40

` Set the starting menu
CMenu=1
do

` Make the current menu equal the variable returned by the function
 CMenu=ShowMenu(CMenu)
 ` If CMenu=6 exit the do/loop
 if CMenu=6 then exit

loop

cls
print "Actual Game"
sync
wait key
end

function ShowMenu(Menu)

cls
 
 ` Find the current menu using the variable "Menu"
 select Menu
 
  ` Main Menu
  case 1
   if Button(20,55,"New Game")=1 then Menu=2
   if Button(20,135,"Multiplayer")=1 then Menu=3
   if Button(20,215,"Options")=1 then Menu=4
   If Button(20,295,"Exit")=1 then Menu=5
  ` Stop this case
  endcase
 
  ` Setup Game
  case 2
   if Button(20,55,"Set up Game")=1 then Menu=1
   if Button(20,135,"Play Game")=1 then Menu=6
  endcase
  
  ` Multiplayer
  case 3
   print "Try Again  ( Menu = 3 )"
   sync
   wait key
   Menu=1
  endcase
  
  ` Options
  case 4
   print "Try Again  ( Menu = 4 )"
   sync
   wait key
   Menu=1
  endcase
  
  ` Exit
  case 5
   print "Try Again  ( Menu = 5 )"
   sync
   wait key
   Menu=1
  endcase
 
 ` Stop the "select"
 endselect

sync

endfunction Menu

function Button(x,y,tex$)

` Change color to bright white
 ink rgb(255,255,255),0
 ` Create a switch
 Pressed=0
 ` Check if the mouse is over the text area
 if mousex()=>x and mousex()<=x+text width(tex$) and mousey()=>y and mousey()<=y+text height(tex$)
  ` If the mouse is over the text area change color to red
  ink rgb(255,0,0),0
  ` Check for a mouse click
  if mouseclick()
   ` If one of the mouse buttons is down wait for the user to let go of the mouse button
   while mouseclick()>0
   endwhile
   ` Turn the switch on
   Pressed=1
  endif
 endif
 
 ` Print the text
 text x,y,tex$

` Leave the function with the switch
endfunction Pressed

+ Code Snippet

cls
Sync On : Sync Rate 40

` Set the starting menu
CMenu=1
do

 ` Make the current menu equal the variable returned by the function
 CMenu=ShowMenu(CMenu)
 ` If CMenu=6 exit the do/loop
 if CMenu=6 then exit

loop

cls
print "Actual Game"
sync
wait key
end


function ShowMenu(Menu)

 cls
 
 ` Find the current menu using the variable "Menu"
 select Menu
 
  ` Main Menu
  case 1
   if Button(20,55,"New Game")=1 then Menu=2
   if Button(20,135,"Multiplayer")=1 then Menu=3
   if Button(20,215,"Options")=1 then Menu=4
   If Button(20,295,"Exit")=1 then Menu=5
  ` Stop this case
  endcase
 
  ` Setup Game
  case 2
   if Button(20,55,"Set up Game")=1 then Menu=1
   if Button(20,135,"Play Game")=1 then Menu=6
  endcase
  
  ` Multiplayer
  case 3
   print "Try Again  ( Menu = 3 )"
   sync
   wait key
   Menu=1
  endcase
  
  ` Options
  case 4
   print "Try Again  ( Menu = 4 )"
   sync
   wait key
   Menu=1
  endcase
  
  ` Exit
  case 5
   print "Try Again  ( Menu = 5 )"
   sync
   wait key
   Menu=1
  endcase
 
 ` Stop the "select"
 endselect

 sync

endfunction Menu


function Button(x,y,tex$)

 ` Change color to bright white
 ink rgb(255,255,255),0
 ` Create a switch
 Pressed=0
 ` Check if the mouse is over the text area
 if mousex()=>x and mousex()<=x+text width(tex$) and mousey()=>y and mousey()<=y+text height(tex$)
  ` If the mouse is over the text area change color to red
  ink rgb(255,0,0),0
  ` Check for a mouse click
  if mouseclick()
   ` If one of the mouse buttons is down wait for the user to let go of the mouse button
   while mouseclick()>0
   endwhile
   ` Turn the switch on
   Pressed=1
  endif
 endif
 
 ` Print the text
 text x,y,tex$

` Leave the function with the switch
endfunction Pressed

Back to top

Profile PM Email

white boy kyle

18

Years of Service

User Offline

Joined: 5th Feb 2007

Location:

Posted: 12th Feb 2007 18:16

Link

Thanks everyone for your reply..

Back to top

Profile PM

Sorry your browser is not supported!

DarkBASIC Discussion / Wtf Keep getting Parameter dont exist