This is just a thought:
You could tilt the skyplain to touch the horizon in the direction the camera is looking:
Sync On
Sync Rate 60
Autocam off
SET AMBIENT LIGHT 100
Sky=1
Grass=2
rem Create Sky Image
Create Bitmap 1,8,8
ink rgb(155,155,255),0
box 0,0,8,8
for d = 1 to 32
ink rgb(255,255,255),0
dot rnd(8),rnd(8)
next d
get image Sky,0,0,8,8
Delete Bitmap 1
rem Create Grass Image
Create Bitmap 1,8,8
ink rgb(0,155,0),0
box 0,0,8,8
for d = 1 to 64
ink rgb(0,rnd(255),0),0
dot rnd(8),rnd(8)
next d
get image Grass,0,0,8,8
Delete Bitmap 1
Make Object Plain 1,1000,1000
Position object 1,0,20,0
xrotate object 1,90
fix object pivot 1:` <-- fix the skyplain pivot
texture object 1,Sky
scale object texture 1,10,10
Make Object Plain 2,1000,1000
Position object 2,0,-10,0
xrotate object 2,90
texture object 2,grass
scale object texture 2,10,10
tang#=4.5:` <-- this is your tilt angle
do
` rotate the camera
yrotate camera 0,wrapvalue(camera angle y(0)+0.25)
`comment out the above line
`and uncomment the next line to walk around
`control camera using arrowkeys 0,0.5,0.25
` get the new camera angle
cangy#=camera angle y(0)
` use the new camera angle and tilt angle to compute the
` x and z axis tilt values
xrotate object 1,sin(wrapvalue(cangy#+90.0))*tang#
zrotate object 1,cos(wrapvalue(cangy#+90.0))*tang#
` just for the fun of it
scroll object texture 1,0.001,0.001
sync
loop
The flaw that I see in this method is you have to limit player movement to the central area of the ground plain.
Hope this helps.
Whatever...
