Sorry your browser is not supported!

input "Num 1 ",n1
input "Num 2 ",n2
input "Num 3 ",n3
if file exist("C:/daemonexample.txt")=1
   delete file "C:/daemonexample.txt"
endif
open to write 1,"C:/daemonexample.txt"
write file 1,n1
write file 1,n2
write file 1,n3
close file 1
end

if file exist("C:/daemonexample.txt")=0
   exit prompt "You have to save before you load","!!!"
else
   open to read 1,"C:/daemonexample.txt"
   read file 1,n1
   read file 1,n2
   read file 1,n3
   close file 1
   print "you saved:"
   print n1
   print n2
   print n3
   wait key
endif
end

rem ***************************************
rem
rem SAVING AND LOADING EXAMPLE USING ARRAYS
rem
rem ***************************************


SYNC ON
Sync Rate 60
autocam off


DIM GameData#(4)
remstart
Slot 1 in the array is for the camera's X position.
Slot 2 is for the Y
And Slot 3 the Z
Slot 4 is for the camera's Y angle. We are saving everything here.
remend



Gosub CREATE_WORLD





do

set cursor 0,0
ink rgb(255,0,0),0
print "MOVE WITH THE ARROW KEYS."
print "PRESS SPACE TO SAVE. PRESS ENTER TO LOAD."




                  rem ***********************************************
                  rem
                  rem SAVING HERE!
                  rem
                  rem ***********************************************


rem If you press space...
if Spacekey()

rem Create a folder to store the game file in only if the game does not already exist.
if file exist("SAVED EXAMPLE DATA/Saved Game File")=0 then Make Directory "SAVED EXAMPLE DATA"

rem Store the camera's data in the game data array.
GameData#(1)=Camera Position X()
GameData#(2)=Camera Position y()
GameData#(3)=Camera Position z()
GameData#(4)=Camera angle y()

rem Save the camera data array.
Save Array "SAVED EXAMPLE DATA/Saved Game File",GameData#(4)

rem Wait for you to release space
while spacekey()>0
sync
endwhile

rem PRint a SAVE COMPLETE message until you press space.
while spacekey()=0
set cursor 100,100
print "SAVE COMPLETE."
sync
endwhile

rem Wait for you to release space.
while spacekey()>0
sync
endwhile

rem END OF IF.
endif


















                  rem *************************************************
                  rem
                  rem LOADING HERE
                  rem
                  rem ************************************************


rem If you press ENTER and the saved game file exists...
if returnkey() and file exist("SAVED EXAMPLE DATA/Saved Game File")=1

rem Load the array.
Load Array "SAVED EXAMPLE DATA/Saved Game File",GameData#(4)

rem Wait for you to release enter.
while returnkey()>0
sync
endwhile

rem Put the camera where the array says. We told it what to say when we saved it.
Position Camera GameData#(1),GameData#(2),GameData#(3)

rem Rotate the camera too.
Yrotate camera GameData#(4)

rem Display a load complete message and wait for you to press enter.
while returnkey()=0
set cursor 100,100
print "LOAD COMPLETE."
sync
endwhile

rem Wait for you to release enter now.
while returnkey()>0
sync
endwhile

rem END OF IF.
endif

















rem Control Camera label.
gosub CONTROL_CAMERA

sync
loop














CONTROL_CAMERA:

Move Camera 10*(Upkey()-Downkey())
yrotate camera wrapvalue(Camera angle y()+rightkey()-Leftkey())

Position Camera Camera Position x(),Get ground height(1,Camera position x(),Camera position z())+40,Camera position z()

if Camera Position x()<0 then Position Camera 0,Get ground height(1,Camera position x(),Camera position z())+40,Camera position z()
if Camera Position x()>10000 then Position Camera 10000,Get ground height(1,Camera position x(),Camera position z())+40,Camera position z()

if Camera Position z()<0 then Position Camera Camera position x(),Get ground height(1,Camera position x(),Camera position z())+40,0
if Camera Position z()>10000 then Position Camera Camera position x(),Get ground height(1,Camera position x(),Camera position z())+40,10000



Scroll object texture 2,0.005,0.005
return






CREATE_WORLD:
Land=1
Sea=2

Create bitmap 1,10,10

for o = 1 to 200
ink rgb(0,rnd(255),0),0
DOT RND(10),RND(10)
next o

get image Land,0,0,10,10
delete bitmap 1

Create bitmap 1,10,10

for o = 1 to 200
ink rgb(55,55,55+RND(200)),0
DOT RND(10),RND(10)
next o

get image Sea,0,0,10,10
delete bitmap 1

Make Matrix 1,10000,10000,30,30

for f = 1 to 29
for g = 1 to 29
if g=f*2 or f=g*2 then set matrix height 1,f,g,200 : set matrix height 1,f,g+1,200 : set matrix height 1,f+1,g+1,200 : set matrix height 1,f+1,g,200
next g
next f

prepare matrix texture 1,1,1,1
update matrix 1



Make Object plain 2,10000,10000
xrotate object 2,90
fix object pivot 2
Scale Object texture 2,20,20
texture object 2,Sea
position object 2,5000,10,5000
return